***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Sep 10, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ4568AP-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     0.811
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=82.2  VTO=2.81  LEVEL=3  VMAX=5e4  ETA=0.006  nfs=6.97e11  gamma=0.62)
Rd     d1    d2    9.235e-3    TC=4.95e-3,1.0e-5
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=66  TBV1=3.585e-4 TBV2=-4.305e-7  CJO=6.46e-10  M=0.6027  VJ=10)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=2.554e-12  N=1.053  RS=4e-8  EG=1.13  TT=20n IKF=6.294 tikf=1e-6)
Rdiode  d1  21    3.015e-3 TC=2.5e-3
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   3.333e-10
.MODEL     DGD    D(cjo=3.283e-10   M=1.258   VJ=5.057)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    2.268e-9
.ENDS PJQ4568AP-AU
*$
